mirror of
https://github.com/Swiftgram/Telegram-iOS.git
synced 2025-09-05 04:10:16 +00:00
465abb1ded
* [License] Simplify the Texture license to be pure Apache 2 (removing ASDK-Licenses) With permission of the Facebook Open Source team, we are simplifying the Texture license so that clients can rely on the Apache 2 terms that most of Texture is already covered by. This means that code originally forked from AsyncDisplayKit will be re-licensed from "BSD 3-clause + PATENTS v2" to Apache 2 without a PATENTS file. After getting confirmation that the updates to these core files look good, we'll propagate this new license header to all files (in this same PR) and get sign-off from all parties before landing. * [License] Update all Texture source files to be pure Apache 2. * Changelog entry for Apache 2 license update. * Revert "[License] Update all Texture source files to be pure Apache 2." This reverts commit ffa0fbbba9717d871dd16c4b07539f2f8208fc2b. * [License] Update all Texture source files to be pure Apache 2, maintaining copyrights. * [License] Update CONTRIBUTING, README, Podspec & Dangerfile.
76 lines
2.8 KiB
Plaintext
76 lines
2.8 KiB
Plaintext
//
|
|
// ASTextKitContext.mm
|
|
// Texture
|
|
//
|
|
// Copyright (c) Facebook, Inc. and its affiliates. All rights reserved.
|
|
// Changes after 4/13/2017 are: Copyright (c) Pinterest, Inc. All rights reserved.
|
|
// Licensed under Apache 2.0: http://www.apache.org/licenses/LICENSE-2.0
|
|
//
|
|
|
|
#import <AsyncDisplayKit/ASTextKitContext.h>
|
|
#import <AsyncDisplayKit/ASLayoutManager.h>
|
|
#import <AsyncDisplayKit/ASThread.h>
|
|
|
|
#include <memory>
|
|
|
|
@implementation ASTextKitContext
|
|
{
|
|
// All TextKit operations (even non-mutative ones) must be executed serially.
|
|
std::shared_ptr<ASDN::Mutex> __instanceLock__;
|
|
|
|
NSLayoutManager *_layoutManager;
|
|
NSTextStorage *_textStorage;
|
|
NSTextContainer *_textContainer;
|
|
}
|
|
|
|
- (instancetype)initWithAttributedString:(NSAttributedString *)attributedString
|
|
lineBreakMode:(NSLineBreakMode)lineBreakMode
|
|
maximumNumberOfLines:(NSUInteger)maximumNumberOfLines
|
|
exclusionPaths:(NSArray *)exclusionPaths
|
|
constrainedSize:(CGSize)constrainedSize
|
|
|
|
{
|
|
if (self = [super init]) {
|
|
// Concurrently initialising TextKit components crashes (rdar://18448377) so we use a global lock.
|
|
// Allocate __staticMutex on the heap to prevent destruction at app exit (https://github.com/TextureGroup/Texture/issues/136)
|
|
static ASDN::StaticMutex& __staticMutex = *new ASDN::StaticMutex;
|
|
ASDN::StaticMutexLocker l(__staticMutex);
|
|
|
|
__instanceLock__ = std::make_shared<ASDN::Mutex>();
|
|
|
|
// Create the TextKit component stack with our default configuration.
|
|
|
|
_textStorage = [[NSTextStorage alloc] init];
|
|
_layoutManager = [[ASLayoutManager alloc] init];
|
|
_layoutManager.usesFontLeading = NO;
|
|
[_textStorage addLayoutManager:_layoutManager];
|
|
|
|
// Instead of calling [NSTextStorage initWithAttributedString:], setting attributedString just after calling addlayoutManager can fix CJK language layout issues.
|
|
// See https://github.com/facebook/AsyncDisplayKit/issues/2894
|
|
if (attributedString) {
|
|
[_textStorage setAttributedString:attributedString];
|
|
}
|
|
|
|
_textContainer = [[NSTextContainer alloc] initWithSize:constrainedSize];
|
|
// We want the text laid out up to the very edges of the container.
|
|
_textContainer.lineFragmentPadding = 0;
|
|
_textContainer.lineBreakMode = lineBreakMode;
|
|
_textContainer.maximumNumberOfLines = maximumNumberOfLines;
|
|
_textContainer.exclusionPaths = exclusionPaths;
|
|
[_layoutManager addTextContainer:_textContainer];
|
|
}
|
|
return self;
|
|
}
|
|
|
|
- (void)performBlockWithLockedTextKitComponents:(void (^)(NSLayoutManager *,
|
|
NSTextStorage *,
|
|
NSTextContainer *))block
|
|
{
|
|
ASDN::MutexSharedLocker l(__instanceLock__);
|
|
if (block) {
|
|
block(_layoutManager, _textStorage, _textContainer);
|
|
}
|
|
}
|
|
|
|
@end
|