mirror of
https://github.com/Swiftgram/Telegram-iOS.git
synced 2025-09-02 18:59:51 +00:00
1410b29b63
* Lock up to yogaRoot during layout to avoid dead lock. 1) lock to root for tree 2) lock self to change parent (& consequently root) 3) Implement ASLocking (tryLock) on ASNodeController 4) add lockPair to try-lock node & controller together 5) lock controllers if they exist in lockToRoot... Disable some asserts due to lock to root. :( LL# No commands remaining. * Add macro so non-Yoga still builds :) * wut
133 lines
2.9 KiB
Plaintext
133 lines
2.9 KiB
Plaintext
//
|
|
// ASNodeController+Beta.mm
|
|
// Texture
|
|
//
|
|
// Copyright (c) Facebook, Inc. and its affiliates. All rights reserved.
|
|
// Changes after 4/13/2017 are: Copyright (c) Pinterest, Inc. All rights reserved.
|
|
// Licensed under Apache 2.0: http://www.apache.org/licenses/LICENSE-2.0
|
|
//
|
|
|
|
#import <AsyncDisplayKit/ASDisplayNodeInternal.h>
|
|
#import <AsyncDisplayKit/ASDisplayNode+FrameworkPrivate.h>
|
|
#import <AsyncDisplayKit/ASNodeController+Beta.h>
|
|
#import <AsyncDisplayKit/ASThread.h>
|
|
|
|
#define _node (_shouldInvertStrongReference ? _weakNode : _strongNode)
|
|
|
|
@implementation ASNodeController
|
|
{
|
|
ASDisplayNode *_strongNode;
|
|
__weak ASDisplayNode *_weakNode;
|
|
ASDN::RecursiveMutex __instanceLock__;
|
|
}
|
|
|
|
- (void)loadNode
|
|
{
|
|
ASLockScopeSelf();
|
|
self.node = [[ASDisplayNode alloc] init];
|
|
}
|
|
|
|
- (ASDisplayNode *)node
|
|
{
|
|
ASLockScopeSelf();
|
|
if (_node == nil) {
|
|
[self loadNode];
|
|
}
|
|
return _node;
|
|
}
|
|
|
|
- (void)setupReferencesWithNode:(ASDisplayNode *)node
|
|
{
|
|
ASLockScopeSelf();
|
|
if (_shouldInvertStrongReference) {
|
|
// The node should own the controller; weak reference from controller to node.
|
|
_weakNode = node;
|
|
_strongNode = nil;
|
|
} else {
|
|
// The controller should own the node; weak reference from node to controller.
|
|
_strongNode = node;
|
|
_weakNode = nil;
|
|
}
|
|
|
|
[node __setNodeController:self];
|
|
[node addInterfaceStateDelegate:self];
|
|
}
|
|
|
|
- (void)setNode:(ASDisplayNode *)node
|
|
{
|
|
ASLockScopeSelf();
|
|
[self setupReferencesWithNode:node];
|
|
}
|
|
|
|
- (void)setShouldInvertStrongReference:(BOOL)shouldInvertStrongReference
|
|
{
|
|
ASLockScopeSelf();
|
|
if (_shouldInvertStrongReference != shouldInvertStrongReference) {
|
|
// Because the BOOL controls which ivar we access, get the node before toggling.
|
|
ASDisplayNode *node = _node;
|
|
_shouldInvertStrongReference = shouldInvertStrongReference;
|
|
[self setupReferencesWithNode:node];
|
|
}
|
|
}
|
|
|
|
// subclass overrides
|
|
- (void)nodeDidLoad {}
|
|
- (void)nodeDidLayout {}
|
|
- (void)nodeWillCalculateLayout:(ASSizeRange)constrainedSize {}
|
|
|
|
- (void)didEnterVisibleState {}
|
|
- (void)didExitVisibleState {}
|
|
|
|
- (void)didEnterDisplayState {}
|
|
- (void)didExitDisplayState {}
|
|
|
|
- (void)didEnterPreloadState {}
|
|
- (void)didExitPreloadState {}
|
|
|
|
- (void)interfaceStateDidChange:(ASInterfaceState)newState
|
|
fromState:(ASInterfaceState)oldState {}
|
|
|
|
- (void)hierarchyDisplayDidFinish {}
|
|
|
|
- (ASLockSet)lockPair {
|
|
ASLockSet lockSet = ASLockSequence(^BOOL(ASAddLockBlock addLock) {
|
|
if (!addLock(_node)) {
|
|
return NO;
|
|
}
|
|
if (!addLock(self)) {
|
|
return NO;
|
|
}
|
|
return YES;
|
|
});
|
|
|
|
return lockSet;
|
|
}
|
|
|
|
#pragma mark NSLocking
|
|
|
|
- (void)lock
|
|
{
|
|
__instanceLock__.lock();
|
|
}
|
|
|
|
- (void)unlock
|
|
{
|
|
__instanceLock__.unlock();
|
|
}
|
|
|
|
- (BOOL)tryLock
|
|
{
|
|
return __instanceLock__.try_lock();
|
|
}
|
|
|
|
@end
|
|
|
|
@implementation ASDisplayNode (ASNodeController)
|
|
|
|
- (ASNodeController *)nodeController
|
|
{
|
|
return _weakNodeController ?: _strongNodeController;
|
|
}
|
|
|
|
@end
|