mirror of
https://github.com/Swiftgram/Telegram-iOS.git
synced 2025-09-15 08:27:52 +00:00
54cda5fdbb
* [ASCellNode] Added indexPath property. * [ASCellNode] Cached the type of scrollView we're using in the node, and placed that logic in setScrollView. * [ASCellNode] Removed table and collection view from indexPath, since they return the index paths from the view-space. * Changed the logic for getting indexPath so that it works even when the cell is not displayed. * [VerticalWithinHorizontalScrolling] Explicitally synthesized indexPath property.
84 lines
2.4 KiB
Plaintext
84 lines
2.4 KiB
Plaintext
//
|
|
// ASIndexedNodeContext.mm
|
|
// AsyncDisplayKit
|
|
//
|
|
// Created by Huy Nguyen on 2/28/16.
|
|
//
|
|
// Copyright (c) 2014-present, Facebook, Inc. All rights reserved.
|
|
// This source code is licensed under the BSD-style license found in the
|
|
// LICENSE file in the root directory of this source tree. An additional grant
|
|
// of patent rights can be found in the PATENTS file in the same directory.
|
|
//
|
|
|
|
#import "ASIndexedNodeContext.h"
|
|
#import "ASEnvironmentInternal.h"
|
|
#import "ASCellNode+Internal.h"
|
|
#import <mutex>
|
|
|
|
@interface ASIndexedNodeContext ()
|
|
|
|
/// Required node block used to allocate a cell node. Nil after the first execution.
|
|
@property (nonatomic, strong) ASCellNodeBlock nodeBlock;
|
|
|
|
@end
|
|
|
|
@implementation ASIndexedNodeContext {
|
|
std::mutex _lock;
|
|
ASCellNode *_node;
|
|
}
|
|
|
|
- (instancetype)initWithNodeBlock:(ASCellNodeBlock)nodeBlock
|
|
indexPath:(NSIndexPath *)indexPath
|
|
supplementaryElementKind:(nullable NSString *)supplementaryElementKind
|
|
constrainedSize:(ASSizeRange)constrainedSize
|
|
environment:(id<ASEnvironment>)environment
|
|
{
|
|
NSAssert(nodeBlock != nil && indexPath != nil, @"Node block and index path must not be nil");
|
|
self = [super init];
|
|
if (self) {
|
|
_nodeBlock = nodeBlock;
|
|
_indexPath = indexPath;
|
|
_supplementaryElementKind = [supplementaryElementKind copy];
|
|
_constrainedSize = constrainedSize;
|
|
_environment = environment;
|
|
_environmentTraitCollection = environment.environmentTraitCollection;
|
|
}
|
|
return self;
|
|
}
|
|
|
|
- (ASCellNode *)node
|
|
{
|
|
std::lock_guard<std::mutex> l(_lock);
|
|
if (_nodeBlock != nil) {
|
|
ASCellNode *node = _nodeBlock();
|
|
_nodeBlock = nil;
|
|
if (node == nil) {
|
|
ASDisplayNodeFailAssert(@"Node block returned nil node! Index path: %@", _indexPath);
|
|
node = [[ASCellNode alloc] init];
|
|
}
|
|
node.cachedIndexPath = _indexPath;
|
|
node.supplementaryElementKind = _supplementaryElementKind;
|
|
node.owningNode = (ASDisplayNode *)_environment;
|
|
ASEnvironmentStatePropagateDown(node, _environmentTraitCollection);
|
|
_node = node;
|
|
}
|
|
return _node;
|
|
}
|
|
|
|
- (ASCellNode *)nodeIfAllocated
|
|
{
|
|
std::lock_guard<std::mutex> l(_lock);
|
|
return _node;
|
|
}
|
|
|
|
+ (NSArray<NSIndexPath *> *)indexPathsFromContexts:(NSArray<ASIndexedNodeContext *> *)contexts
|
|
{
|
|
NSMutableArray *result = [NSMutableArray arrayWithCapacity:contexts.count];
|
|
for (ASIndexedNodeContext *ctx in contexts) {
|
|
[result addObject:ctx.indexPath];
|
|
}
|
|
return result;
|
|
}
|
|
|
|
@end
|