mirror of
https://github.com/Swiftgram/Telegram-iOS.git
synced 2025-09-13 07:39:37 +00:00
465abb1ded
* [License] Simplify the Texture license to be pure Apache 2 (removing ASDK-Licenses) With permission of the Facebook Open Source team, we are simplifying the Texture license so that clients can rely on the Apache 2 terms that most of Texture is already covered by. This means that code originally forked from AsyncDisplayKit will be re-licensed from "BSD 3-clause + PATENTS v2" to Apache 2 without a PATENTS file. After getting confirmation that the updates to these core files look good, we'll propagate this new license header to all files (in this same PR) and get sign-off from all parties before landing. * [License] Update all Texture source files to be pure Apache 2. * Changelog entry for Apache 2 license update. * Revert "[License] Update all Texture source files to be pure Apache 2." This reverts commit ffa0fbbba9717d871dd16c4b07539f2f8208fc2b. * [License] Update all Texture source files to be pure Apache 2, maintaining copyrights. * [License] Update CONTRIBUTING, README, Podspec & Dangerfile.
75 lines
1.5 KiB
Plaintext
75 lines
1.5 KiB
Plaintext
//
|
|
// ASRectMap.mm
|
|
// Texture
|
|
//
|
|
// Copyright (c) Pinterest, Inc. All rights reserved.
|
|
// Licensed under Apache 2.0: http://www.apache.org/licenses/LICENSE-2.0
|
|
//
|
|
|
|
#import "ASRectMap.h"
|
|
#import "ASObjectDescriptionHelpers.h"
|
|
#import <UIKit/UIGeometry.h>
|
|
#import <unordered_map>
|
|
|
|
@implementation ASRectMap {
|
|
std::unordered_map<void *, CGRect> _map;
|
|
}
|
|
|
|
+ (ASRectMap *)rectMapForWeakObjectPointers NS_RETURNS_RETAINED
|
|
{
|
|
return [[self alloc] init];
|
|
}
|
|
|
|
- (CGRect)rectForKey:(id)key
|
|
{
|
|
let result = _map.find((__bridge void *)key);
|
|
if (result != _map.end()) {
|
|
// result->first is the key; result->second is the value, a CGRect.
|
|
return result->second;
|
|
} else {
|
|
return CGRectNull;
|
|
}
|
|
}
|
|
|
|
- (void)setRect:(CGRect)rect forKey:(id)key
|
|
{
|
|
if (key) {
|
|
_map[(__bridge void *)key] = rect;
|
|
}
|
|
}
|
|
|
|
- (void)removeRectForKey:(id)key
|
|
{
|
|
if (key) {
|
|
_map.erase((__bridge void *)key);
|
|
}
|
|
}
|
|
|
|
- (id)copyWithZone:(NSZone *)zone
|
|
{
|
|
ASRectMap *copy = [ASRectMap rectMapForWeakObjectPointers];
|
|
copy->_map = _map;
|
|
return copy;
|
|
}
|
|
|
|
- (NSMutableArray<NSDictionary *> *)propertiesForDescription
|
|
{
|
|
NSMutableArray *result = [NSMutableArray array];
|
|
|
|
// { ptr1->rect1 ptr2->rect2 ptr3->rect3 }
|
|
NSMutableString *str = [NSMutableString string];
|
|
for (let &e : _map) {
|
|
[str appendFormat:@" %@->%@", e.first, NSStringFromCGRect(e.second)];
|
|
}
|
|
[result addObject:@{ @"ASRectMap": str }];
|
|
|
|
return result;
|
|
}
|
|
|
|
- (NSString *)description
|
|
{
|
|
return ASObjectDescriptionMakeWithoutObject([self propertiesForDescription]);
|
|
}
|
|
|
|
@end
|