mirror of
https://github.com/Swiftgram/Telegram-iOS.git
synced 2025-09-13 15:48:18 +00:00
c2ea7cfeac
* Separate dataSource & UIKit index spaces Beef up our supplementary node support Make the API way better Go nuts Add a unit test for UICollectionView's handling of reloadData inside batch updates Wrap indexPathForNode: in a cache Convert index paths in delegate methods Go back on table view Put collection view back Switch up the API Move most ASCollectionView API to ASCollectionNode Move most table logic over to ASTableNode Do the things More conversion work Keep on keepin' on Get table view delegate API done More porting Simplify Clear the delegate More cleanup Move more stuff around Remove pointless file Re-add some API Put back more API Use the right flag * Some cleanup * Remove incorrect comment * Tweak the API * Put back a couple methods * update example projects (note: ASCollectionView deprecation warnings expected) * change reloadDataWithCompletion:nil --> reloadData * Clean up rebase * Make deprecated numberOfItemsInSection methods optional * Use the right flag * Address nits * update ASDKTube, ASDKgram & ASViewController examples
82 lines
2.4 KiB
Plaintext
82 lines
2.4 KiB
Plaintext
//
|
|
// ASIndexedNodeContext.mm
|
|
// AsyncDisplayKit
|
|
//
|
|
// Created by Huy Nguyen on 2/28/16.
|
|
//
|
|
// Copyright (c) 2014-present, Facebook, Inc. All rights reserved.
|
|
// This source code is licensed under the BSD-style license found in the
|
|
// LICENSE file in the root directory of this source tree. An additional grant
|
|
// of patent rights can be found in the PATENTS file in the same directory.
|
|
//
|
|
|
|
#import "ASIndexedNodeContext.h"
|
|
#import "ASEnvironmentInternal.h"
|
|
#import "ASCellNode+Internal.h"
|
|
#import <mutex>
|
|
|
|
@interface ASIndexedNodeContext ()
|
|
|
|
/// Required node block used to allocate a cell node. Nil after the first execution.
|
|
@property (nonatomic, strong) ASCellNodeBlock nodeBlock;
|
|
|
|
@end
|
|
|
|
@implementation ASIndexedNodeContext {
|
|
std::mutex _lock;
|
|
ASCellNode *_node;
|
|
}
|
|
|
|
- (instancetype)initWithNodeBlock:(ASCellNodeBlock)nodeBlock
|
|
indexPath:(NSIndexPath *)indexPath
|
|
supplementaryElementKind:(nullable NSString *)supplementaryElementKind
|
|
constrainedSize:(ASSizeRange)constrainedSize
|
|
environmentTraitCollection:(ASEnvironmentTraitCollection)environmentTraitCollection
|
|
{
|
|
NSAssert(nodeBlock != nil && indexPath != nil, @"Node block and index path must not be nil");
|
|
self = [super init];
|
|
if (self) {
|
|
_nodeBlock = nodeBlock;
|
|
_indexPath = indexPath;
|
|
_supplementaryElementKind = [supplementaryElementKind copy];
|
|
_constrainedSize = constrainedSize;
|
|
_environmentTraitCollection = environmentTraitCollection;
|
|
}
|
|
return self;
|
|
}
|
|
|
|
- (ASCellNode *)node
|
|
{
|
|
std::lock_guard<std::mutex> l(_lock);
|
|
if (_nodeBlock != nil) {
|
|
ASCellNode *node = _nodeBlock();
|
|
_nodeBlock = nil;
|
|
if (node == nil) {
|
|
ASDisplayNodeFailAssert(@"Node block returned nil node! Index path: %@", _indexPath);
|
|
node = [[ASCellNode alloc] init];
|
|
}
|
|
node.cachedIndexPath = _indexPath;
|
|
node.supplementaryElementKind = _supplementaryElementKind;
|
|
ASEnvironmentStatePropagateDown(node, _environmentTraitCollection);
|
|
_node = node;
|
|
}
|
|
return _node;
|
|
}
|
|
|
|
- (ASCellNode *)nodeIfAllocated
|
|
{
|
|
std::lock_guard<std::mutex> l(_lock);
|
|
return _node;
|
|
}
|
|
|
|
+ (NSArray<NSIndexPath *> *)indexPathsFromContexts:(NSArray<ASIndexedNodeContext *> *)contexts
|
|
{
|
|
NSMutableArray *result = [NSMutableArray arrayWithCapacity:contexts.count];
|
|
for (ASIndexedNodeContext *ctx in contexts) {
|
|
[result addObject:ctx.indexPath];
|
|
}
|
|
return result;
|
|
}
|
|
|
|
@end
|